ArduinoでGPIB・イーサネットアダプタ

また「イーサネットアダプタ」ですｗ

計測機器には、GPIBコネクタのついてるものが結構あります。

そうなりゃ当然、このコネクタを介して計算機から計測器を制御して、測定を自動化してやろう、
という野望も湧いてくる、ってもんです（私の場合は、それが仕事の１つなんですが）。

ですが、GPIBインタ-フェイスカードが引くくらい高い。
※GPIBの場合、ケーブルも高くて二重苦です。


というわけで、ArduinoでGPIBインターフェイスを自作してみることにしました。
ついでにEthernet ShieldでLANに載せてみます。

GPIBは、３線式ハンドシェイクによるパラレルバスで、信号は負論理のTTLレベルです。
なので、前回のRS-232Cのようなレベル変換回路は不必要で、Arduinoに直結できます。

ラインの本数ですが、バス管理ラインも含めると全部で16本のラインがあります。
（DIO1-8, NRFD, DAV, NDAC, ATN, EOI, IFC, REN, SRQ、GND含めると計17本）

Arduinoで使えるピン数は、digitalが14本、analog（digitalとしても利用可）が6本の計20本。

「余裕じゃん」と思ったのですが、Ethernet Shield使うのでSPIのためにdigital10-13の４本は
開けておかなければなりません。 また、シリアル用のdigital0・1も開けておかないと、
デバックでしんどいことになります。

すると、使えるピン数は14本、と足りなくなってしまいました。

SRQは、バスに接続された機器から（用紙切れや機器異常の）サービス要求を
バスコントローラへアサートするラインですが、この機能を使わないことにします。

またRENは、接続された機器の操作モードをリモート/ローカルに切り替えるためのラインですが、
LOWに落としておけば常時リモートなので、今回は使わないことにします。

これでなんとかピン数が足りました。


以下が、今回書いたスケッチです。
MACアドレスとかIPアドレスは伏せ字にしてあります。

/*
 * GIPB Ether Adapter
*/

#include <string.h>
#include <Ethernet.h>

// Define PIN name
#define DIO1  19
#define DIO2  18
#define DIO3  17
#define DIO4  16
#define DIO5  15
#define DIO6  14
#define DIO7  9
#define DIO8  8
#define EOI   6
#define DAV   5
#define NRFD  4
#define NDAC  3
#define IFC   7
#define ATN   2
#define REN   GND
#define SRQ   GND

// set MAC & IP
byte mac[] = { 0x〇〇, 0x〇〇, 0x〇〇, 0x〇〇, 0x〇〇, 0x〇〇 };
byte ip[] = { 〇〇〇, 〇〇〇, 〇〇〇, 〇〇〇 };
byte gateway[] = { 〇〇〇, 〇〇〇, 〇〇〇, 〇〇〇 };
byte subnet[] = { 〇〇〇, 〇〇〇, 〇〇〇, 〇〇〇 };
Server server(〇〇〇);

// set Commando val
char com[256] = "";
char c = 0;
int p = 0;

void setup() {
  // initialize the ethernet device
  Ethernet.begin(mac, ip, gateway, subnet);
  // start listening for clients
  server.begin();
  
  // initialize gpib line
  pinMode(EOI, OUTPUT); digitalWrite(EOI, HIGH);
  pinMode(DAV, OUTPUT); digitalWrite(DAV, HIGH); 
  pinMode(NDAC, OUTPUT); digitalWrite(NDAC, LOW);
  pinMode(NRFD, OUTPUT); digitalWrite(NRFD, LOW);

}

void loop() {
  int i;
  
  Client client = server.available();
  
  if (client) {
    while (client.connected()) {
      if (0 < client.available()) {
        c = client.read();
        *(com + p) = c; *(com + p + 1) = 0; 
        p++;
      }
      
      if (';' == c) {
        *(com + p - 1) = 0;
        if (0 == strcmp("IFC", com)) { gpibIFC();
        } else if (0 == strcmp("DCL", com)) { gpibDCL();
        } else if (0 == strcmp("STA", com)) { gpibLineStatus();
        } else {
          char command;
          int addr;
          char option[255];
          sscanf(com, "%c%2d", &command, &addr);
          for (i = 4 ; i < strlen(com) ; i++) {
            option[i-4] = *(com + i);
          } option[i-4] = 0;
          strcat(option, "\r\n");
          
          if ('W' == command) { 
            gpibTalk((byte)addr, option);
          } else if ('R' == command) {
            char str[255] = "";
            gpibListen((byte)addr, str, "\r\n"); server.println(str);
          } else if ('C' == command) {
            gpibSDC((byte)addr);
          } 
        }
        *com = 0; p = 0; c = 0;
      }
    }
  }
}

void gpibLineStatus(void) {
  pinMode(ATN, INPUT); digitalWrite(ATN, HIGH); Serial.print(" ATN="); Serial.print(digitalRead(ATN));
  pinMode(DAV, INPUT); digitalWrite(DAV, HIGH); Serial.print(", DAV="); Serial.print(digitalRead(DAV));
  pinMode(NRFD, INPUT); digitalWrite(NRFD, HIGH); Serial.print(", NRFD="); Serial.print(digitalRead(NRFD));
  pinMode(NDAC, INPUT); digitalWrite(NDAC, HIGH); Serial.print(", NDAC="); Serial.print(digitalRead(NDAC));
  pinMode(EOI, INPUT); digitalWrite(EOI, HIGH); Serial.print(", EOI="); Serial.print(digitalRead(EOI));
  Serial.print(", DIO8-1=");
  pinMode(DIO8, INPUT); digitalWrite(DIO8, HIGH); Serial.print(digitalRead(DIO8));
  pinMode(DIO7, INPUT); digitalWrite(DIO7, HIGH); Serial.print(digitalRead(DIO7));
  pinMode(DIO6, INPUT); digitalWrite(DIO6, HIGH); Serial.print(digitalRead(DIO6));
  pinMode(DIO5, INPUT); digitalWrite(DIO5, HIGH); Serial.print(digitalRead(DIO5));
  pinMode(DIO4, INPUT); digitalWrite(DIO4, HIGH); Serial.print(digitalRead(DIO4));
  pinMode(DIO3, INPUT); digitalWrite(DIO3, HIGH); Serial.print(digitalRead(DIO3));
  pinMode(DIO2, INPUT); digitalWrite(DIO2, HIGH); Serial.print(digitalRead(DIO2));
  pinMode(DIO1, INPUT); digitalWrite(DIO1, HIGH); Serial.println(digitalRead(DIO1));

}

byte get_dio() {
  byte x = 0;
  
  pinMode(DIO1, INPUT); bitWrite(x, 0, !digitalRead(DIO1));
  pinMode(DIO2, INPUT); bitWrite(x, 1, !digitalRead(DIO2));
  pinMode(DIO3, INPUT); bitWrite(x, 2, !digitalRead(DIO3));
  pinMode(DIO4, INPUT); bitWrite(x, 3, !digitalRead(DIO4));
  pinMode(DIO5, INPUT); bitWrite(x, 4, !digitalRead(DIO5));
  pinMode(DIO6, INPUT); bitWrite(x, 5, !digitalRead(DIO6));
  pinMode(DIO7, INPUT); bitWrite(x, 6, !digitalRead(DIO7));
  pinMode(DIO8, INPUT); bitWrite(x, 7, !digitalRead(DIO8));
  
  return x;
}

void set_dio(byte x) {
  
  pinMode(DIO1, OUTPUT); digitalWrite(DIO1, bitRead(~x, 0));
  pinMode(DIO2, OUTPUT); digitalWrite(DIO2, bitRead(~x, 1));
  pinMode(DIO3, OUTPUT); digitalWrite(DIO3, bitRead(~x, 2));
  pinMode(DIO4, OUTPUT); digitalWrite(DIO4, bitRead(~x, 3));
  pinMode(DIO5, OUTPUT); digitalWrite(DIO5, bitRead(~x, 4));
  pinMode(DIO6, OUTPUT); digitalWrite(DIO6, bitRead(~x, 5));
  pinMode(DIO7, OUTPUT); digitalWrite(DIO7, bitRead(~x, 6));
  pinMode(DIO8, OUTPUT); digitalWrite(DIO8, bitRead(~x, 7));
  
}

void gpibWrite(byte data) {
  // wait until (LOW == NDAC)
  pinMode(NDAC, INPUT);
  while (HIGH == digitalRead(NDAC)) { ; }
  
  // output data to DIO
  set_dio(data);
  
  // wait until (HIGH == NRFD)
  pinMode(NRFD, INPUT);
  while (LOW == digitalRead(NRFD)) { ; }
  
  // validate data
  pinMode(DAV, OUTPUT);
  digitalWrite(DAV, LOW);
  
  // wait until (HIGH == NDAC)
  while (LOW == digitalRead(NDAC)) { ; }
  
  digitalWrite(DAV, HIGH);
  set_dio(0); delayMicroseconds(10);
  
  return;
}

boolean gpibRead(byte *data) {
  
  boolean ret = false;
  
  // prepare to listen
  pinMode(NRFD, OUTPUT);
  digitalWrite(NRFD, HIGH);
  
  // wait until (LOW == DAV)
  pinMode(DAV, INPUT);
  while (HIGH == digitalRead(DAV)) { ; }
  
  // Ready for data
  digitalWrite(NRFD, LOW);
  
  // read from DIO
  *data = get_dio();
  
  // check EOI
  pinMode(EOI, INPUT);
  if (LOW == digitalRead(EOI)) {
    ret = true;
  } else {
    ret = false;
  }
  
  // data accepted
  pinMode(NDAC, OUTPUT);
  digitalWrite(NDAC, HIGH);
  
  // wait until invalid data
  while (LOW == digitalRead(DAV)) { ; }
  digitalWrite(NDAC, LOW);
  
  return ret; // return true when EOI==LOW
}

void gpibTalk(byte addr, char *str) {
  // attention
  pinMode(EOI, OUTPUT);
  digitalWrite(EOI, HIGH);
  pinMode(ATN, OUTPUT);
  digitalWrite(ATN, LOW); delayMicroseconds(30);
  
  // unlisten
  gpibWrite(0x3F); delayMicroseconds(20);
  
  // talker address
  gpibWrite(0x40); delayMicroseconds(20);
  
  // listener address
  gpibWrite((byte)(0x20 + addr)); delayMicroseconds(20);
  
  // end of attention
  digitalWrite(ATN, HIGH); delayMicroseconds(20);
    
  // write string
  while (0 != *(str + 1)) {
    gpibWrite(*str); delayMicroseconds(20);
    str++;
  }
  
  // write last char
  digitalWrite(EOI, LOW);
  gpibWrite(*str); delayMicroseconds(20);  
  digitalWrite(EOI, HIGH);
  
}

boolean gpibListen(byte addr, char *str, char* del) {
  // attention
  pinMode(ATN, OUTPUT);
  digitalWrite(ATN, LOW); delayMicroseconds(30);
  
  // unlisten
  gpibWrite(0x3F); delayMicroseconds(20);
  
  // talker address
  gpibWrite((byte)(0x40 + addr)); delayMicroseconds(20);
  
  // listener address
  gpibWrite(0x20); delayMicroseconds(20);
  
  // end of attention
  pinMode(NRFD, OUTPUT); digitalWrite(NRFD, LOW);
  pinMode(NDAC, OUTPUT); digitalWrite(NDAC, LOW);
  
  delayMicroseconds(10);
  digitalWrite(ATN, HIGH); delayMicroseconds(20);
  
  // recieve data
  int i, s, len = strlen(del);
  byte c;
  boolean isLast, isDel;
  
  s = 0;
  do {
    isLast = gpibRead(&c); *(str) = c;
    isDel = true;
    for (i = 0 ; i < len ; i++) {
      isDel = isDel & (*(str - i) == *(del + len - i - 1));
    }
    str++;
  } while (!(isLast || isDel));
  *(str) = 0;

  return true;
}

void gpibIFC(void) {
  pinMode(IFC, OUTPUT); digitalWrite(IFC,LOW); delayMicroseconds(128);
  digitalWrite(IFC, HIGH);
}

void gpibDCL(void) {
  // attention
  pinMode(ATN, OUTPUT); digitalWrite(ATN, LOW); delayMicroseconds(10);
  
  // send DCL
  gpibWrite(0x14); delayMicroseconds(10);
  
  // end of attention
  digitalWrite(ATN, HIGH); delayMicroseconds(20);
}

void gpibSDC(byte addr) {
  // attention
  pinMode(ATN, OUTPUT); digitalWrite(ATN, LOW); delayMicroseconds(10);
  
  // unlisten
  gpibWrite(0x3F); delayMicroseconds(10);
  
  // send ADDRESS for device clear
  gpibWrite((byte)(32 + addr)); delayMicroseconds(10);
  
  // send SDC
  gpibWrite(0x04); delayMicroseconds(10);
  
  // end of attention
  digitalWrite(ATN, HIGH); delayMicroseconds(20);
}

ピンアサインは全部digitalで使ってるので適当です。
多分、どこに繋いでも動くと思います。

メイン部分のやってることは単純で、setupでサーバ立てて、loopでリスンして、
クライアントからのコマンド文字列を解釈して、GPIBへ流してるだけです。

コマンド文字列のデリミタはセミコロン（;）です。

バス管理コマンドとして、「IFC」と「DCL」を実装しています。
また、アドレス指定デバイスクリアコマンドとして「C（アドレス）」も実装しています。

リモート/ローカル関連のコマンドは、RENが常時GNDなので実装しませんでした。
また、トリガーコマンドも未実装です（私個人が使わないので）。

ポール関連コマンドもSRQライン使ってないので未実装です。

おまけとして、ライン状態を取得する「STA」コマンドを実装しておきました。

GPIB接続された機器とのコマンドのやりとりは、
コマンド送信が「W（リスナアドレス）=(コマンド文字列)」、
リプライ受信が「R（トーカアドレス）」となっています。

このコマンドインタープリタ部分は、かなり適当に書いたので、
ちょっとしたエラーで簡単にハングアップしますｗ
実用するには、もっと真面目に書かないといけないでしょう。

GPIB関連の処理は、面倒くさかったので、ライブラリにせずにベタ書きにしました。
また、C++忘れたので、クラスにもしませんでしたｗ。

簡単に解説すると、

set_dio(), get_dio()が、DIO1-8へのバイト書き込みと読み出しです。

gpibWrite(), gpibRead()が、 ３線式ハンドシェイクを行いながら、
トーカ・リスナ間で１バイトのデータ送受信を行う関数です。

gpibTalk(), gpibListen()が、上記関数を使って、GPIBコマンドを
送受信する関数です。
簡単に実装するために、複数のリスナアドレス指定はできないようになっています。

各ステップに入っているウェイトは適当です。なくても動くかも知れません（動かないかも知れませんが）。
GPIBコマンドのデリミタは「CR+LF」に決め打ちしています。


スケッチ書けたので、実際に機器繋いでテストです。

高いケーブルを覚悟決めてエイヤっとぶった切って、切ったほうはハンダ上げします。
DIO1-8以外のラインには専用のGNDラインがあるのですが、全部まとめて１本にします。

※コネクタ形状が、セントロニクスフルピッチ24ピンと同じなので、
※そのケーブルがあれば良かったのですが、手元にありませんでした。

テスト用に、使っていない計測機器を集めてきて、全部を接続します。

後ろからでわかりにくいですが、
上のほうがエレクトロメータ（KEITHLEY 6514）、
下がプログラマブル電流アンプ（KEITHLEY 428-PROG）です。

これらは、フロントパネルの16セグにテキストメッセージを表示させることができますので、

こんなこともできますｗ

ちなみに、このために送ったコマンドは、

こんな感じです。



ArduinoでのGPIB制御は、ネット上に実装例は未だに無く（探した限りでは）、
Playgroundにも情報がありません（フォーラムでの質問はありましたが…）。

また、GPIBコンバータもRS-232Cのものは、ネット上に回路やキットの情報があるのですが、
イーサネットのはなかなか見当たりません。

この投稿が、誰かの役に立てば幸いです（損害や不利益は関知しませんがｗ）。

あと、ありえないとは思いますが、このまま商品化とかしないようにｗ
出来のイイ似たものが既に市販されてますからｗ